;;webscript fieldbrokerlist( Integer nodeId, Integer listLen, RecArray brokersRec, Integer libraryReference, Assoc template = Undefined, Record request = undefined )

// listLen, the length of pulldownn menu (Usually 1 for popup or 4 for multi-select)
// recs, all brokers
// nodeID is deprecated

	<!-- File: websbroker/fieldbrokerlist.html --->

	;Dynamic	rec
	;List		hilightList = { libraryReference }
	;String		locationName
	;String		withinQuery
	;String		locationId

	;Boolean	IsInList = False
	;Boolean	doPopup = ( listLen == 1 )

	;Integer 	i = 1
	;String		key = 'collections'

	;Object		bsModule = $Kernel.ModuleSubsystem.GetItem("webbrokeredsearch" )

	;if IsDefined( template )
		;locationName = template.locationName
		;withinQuery = template.withinQuery
		;locationId = template.locationId

		;if IsDefined( template.collections )
			;hilightList = template.collections.components
		;end

		// try from request first
		;if IsDefined( request )
			;if IsFeature( request,'collections_search_selected_list' ) || IsFeature( request,'collections_search_selected' )
				;hilightList =_GetBrokerListFromRequest( request )
			;end
		;end
	;end

	// try from request
	;if IsUndefined( locationId ) && IsDefined( request )
		;if Length( request.locationId ) > 0 && request.locationName == 'TRUE' && IsDefined( request.withinQuery )
			;locationName = request.locationName
			;withinQuery = request.withinQuery
			;locationId = request.locationId
		;end
	;end

	;if ( ( Length( locationName ) > 0 ) && doPopup )
		;if IsDefined( bsModule )
		  <SELECT CLASS="searchBut" NAME="`key + '_search_selected'`" SIZE="1" ONCHANGE="if ( this.selectedIndex == 1 ) {urlStr = this.options[ this.selectedIndex ].value + '&Fulltext_value1='+ escape( this.form.Fulltext_value1.value ) + '&Fulltext_mode1=' +this.form.Fulltext_mode1.value ; location.href = urlStr };if (this.selectedIndex == 2 ) { this.selectedIndex = 0};if (this.selectedIndex == this.length - 1 ) { urlStr = this.options[this.selectedIndex ].value + '&BSMustContain=' +escape(this.form.Fulltext_value1.value ); location.href = urlStr };">		;else
		  <SELECT CLASS="searchBut" NAME="`key +'_search_selected'`" SIZE="1" ONCHANGE="if ( this.selectedIndex == 1 ) {urlStr = this.options[ this.selectedIndex ].value + '&Fulltext_value1='+ escape( this.form.Fulltext_value1.value ) + '&Fulltext_mode1=' +this.form.Fulltext_mode1.value ; location.href = urlStr };if (this.selectedIndex == 2 ) { this.selectedIndex = 0}">		;end
		;else
			<SELECT CLASS="searchBut" `( !doPopup ) ? " MULTIPLE" :""` NAME="`key + '_search_selected'`" SIZE="`listLen`">	;end

	;if Length( withinQuery ) > 0
		// Display the within line if this is a popup, if it is a selected scope, or
		// if FromHereExpanded is 'TRUE' because we just came from a popup.
		;if ( doPopup || _WithinSelected( hilightList ) || request.FromHereExpanded == 'TRUE' )
			<OPTION SELECTED VALUE="`Str.String( brokersRec[1 ].DATAID ) + '&' + locationId + '&' + locationName `">`brokersRec[ 1].NAME`</OPTION>
		;end

		;if doPopup
			<OPTION VALUE="`.URL()`?func=ll&objType=258&objAction=searchprompt&locationId=`locationId`&locationName=`Web.Escape( locationName)`&withinQuery=TRUE&FromHereExpanded=TRUE">`[WebSBroker_HTMLLabel.FromHereExpanded]`</OPTION>
			<OPTION VALUE="">--------</OPTION>
		;end
		;if ( doPopup || ( IsFeature( request,'FromHereExpanded' ) && request.FromHereExpanded == 'TRUE' ) )
			;for i = 2 to Length( brokersRec )
				<OPTION VALUE="`brokersRec[ i].DATAID`">`brokersRec[ i ].NAME`</OPTION>
			;end
		;else
			;for i = 2 to Length( brokersRec )
				;rec = brokersRec[ i ]
				;IsInList = False
				;if ( ( rec.DATAID in hilightList ) && (rec.DATAID != libraryReference ) )
					;IsInList = True
				;end
				<OPTION `( IsInList ) ? "SELECTED" : ""`VALUE="`rec.DATAID`">`rec.NAME`</OPTION>
			;end
		;end
	;else
		;for i = 1 to Length( brokersRec )
			;rec = brokersRec[ i ]
			;IsInList = False
			;if ( ( rec.DATAID in hilightList ) || ( i == 1&& noDefaultSelection( brokersRec, hilightList ) ) )
				;IsInList = True
			;end
			<OPTION `( IsInList ) ? "SELECTED" : ""`VALUE="`rec.DATAID`">`rec.NAME`</OPTION>
		;end
	;end
	;boolean showGlobalSlice = true;
	;if IsDefined( request )
      ;if IsFeature( request, 'objAction' ) && ( !Str.CmpI(request.objAction ,'searchprompt' ) )
        ;showGlobalSlice = false;
      ;end
    ;end
	;if ( showGlobalSlice ) && IsDefined( bsModule )
			<OPTION VALUE="">--------</OPTION>
			<OPTION VALUE='GlobalSearch'>`[WebBrokeredSearch_HTMLLabel.GlobalSearch]`</OPTION>
			<OPTION VALUE="`.URL()`?func=bs.prompt">`[WebBrokeredSearch_HTMLLabel.GlobalSearchExpanded]`</OPTION>
    ;end
	</SELECT>

	<script>
	var arr_optionsValue = new Array(); // array to hold the Value of the OPTIONS
	var arr_optionsText = new Array(); // array to hold the Text of the OPTIONS
	var ds; // Index of current selected Option
	var theDD; // reference to the Drop Down
	var startPos=0; // reference to the first Slice

	 // if on the Standard Search Page
	if (document.SearchBarForm)
	{
		theDD=document.SearchBarForm.collections_search_selected;
	}
	// if on the Advanced Search Page
	if (document.searchFrm)
	{
		theDD=document.searchFrm.collections_search_selected;
	}

	// find the location of the seperator
	for (count=0;count<theDD.options.length;count++)
	{
		if (theDD.options[count].text=="--------")
		{
			startPos=count+1;
			break;
		}
	}

	// get the text of each OPTION tag
	for (count=startPos;count<theDD.options.length;count++)
	{
		arr_optionsText[count] = theDD.options[count].text;
	}

	// sort the array
	arr_optionsText.sort();

	// add the values
	for (i=0;i<arr_optionsText.length;i++)
	{
		for (j=0;j<theDD.options.length;j++)
		{
			if (theDD.options[j].text==arr_optionsText[i])
			{
				arr_optionsValue[i]=theDD.options[j].value;
			}
		}
	}

	// cut the list to just be the main search areas
	theDD.options.length=startPos;

	// add the slices in alphabetical order
	for (i=0;i<(arr_optionsText.length-startPos);i++)
	{
		theDD.options[i+startPos]= new Option(arr_optionsText[i],arr_optionsValue[i]);
	}
</script>
;;end

;Function Boolean _WithinSelected( List hilightList )
	;Boolean		retval = FALSE
	;Dynamic		d


	;for d in hilightList
		;if ( Type( d ) == StringType )
			;retval = TRUE
			;break
		;end
	;end

	;return retval
;end

;function List _GetBrokerListFromRequest( request )

	;List 		retVal
	;String		item
	;Integer	itemInt
	;List		collections = {}


	;if IsFeature( request, 'collections_search_selected_list' )
		;collections = request.collections_search_selected_list
	;elseif IsFeature( request, 'collections_search_selected' )
		;collections = { request.collections_search_selected }
	;end

	;for item in collections
		;itemInt = Str.StringToInteger( item )
		;if IsDefined( itemInt )
			;retVal = { @retVal, itemInt }
		;else
			;retVal = { @retVal, item }
		;end
	;end

	;return retVal

;end

;Function Boolean noDefaultSelection( RecArray brokersRec, List highlightList )

	;Record rec

	;for rec in brokersRec
		;if ( rec.DATAID in highlightlist )
			;return False
		;end
	;end

	;return True
;end